Publishers of technology books, eBooks, and videos for creative people

Home > Articles > Web Design & Development > PHP/MySQL/Scripting

  • Print
  • + Share This
This chapter is from the book

Finding Items by Property

The previous section describes all the methods used to locate or reference items by their location in their parent container or in relation to each other. Although a useful and valuable means of locating items, finding items by location is not the only way to find the items you need to process.

As you learned in the example at the start of this chapter, referring to items by the value of their properties is more useful when you know what you want but not where it is. AppleScript has an excellent built-in means of finding the items you need by using an easy-to-understand query syntax.

For example, how would you write a script to locate every item of the startup disk whose name begins with S? The answer is that you just wrote it! Script 4.26 shows that it is exactly what you would say in conversation.

Script 4.26.

   tell application "Finder" to ¬
       get every item of the startup disk whose name begins with "S"
   --> returns: {folder "System" of startup disk of application "Finder"}

The result of this query is a list of references to the items at the top level of the startup disk whose name begins with the letter S. If no items match the query, an empty list is returned. If many items match the query, a reference to each of them is returned in the list.

The Structure of a Query

Let's examine the various components that make up the previous query. It begins with a keyword that identifies how many or which items are to be referenced. Examples are every, first, last, and some.

This query:

   every item of the startup disk whose name begins with "S"

returns a list of references to all the items whose properties match the request, while this query:

   the first item of the startup disk whose name begins with "S"

returns a single reference to the first item whose properties match the request. Likewise, this query:

   the last item of the startup disk whose name begins with "S"

returns a single reference to the last item whose properties match the request.

Another way to request references to all matching items is to use the plural form of the class of the objects you are searching for, such as this:

   items of the startup disk whose name begins with "S"

or this:

   folders of the startup disk whose name begins with "S"

The plural items is equivalent to the term every item, and you can use them interchangeably.

The next component of the query begins with the term whose and specifies the target property and the target property's value.

This specification is composed of the title of the target property (in this case, the name property), a comparison operator (in this case, begins with), and the value of the target property (in this case, the letter S). Each of the elements can be changed to suit the needs of the query. Here are some examples.

Original query:

   every item of the startup disk whose name begins with "S"

Changing the location indicator:

   the first item of the startup disk whose name begins with "S"
   the last item of the startup disk whose name begins with "S"
   some item of the startup disk whose name begins with "S"

Changing the comparison operator:

   every item of the startup disk whose name ends with "S"
   every item of the startup disk whose name contains "S"
   every item of the startup disk whose name does not contain "S"

Changing the value of the target property:

   every item of the startup disk whose name ends with "q"
   every item of the startup disk whose name ends with ".zip"

As with the English language, innumerable variations are available for the syntax of the query, providing the ability to search for exactly the items you desire.

For your reference, the following sections are partial lists of the operators used by the AppleScript language:

Containment Operators

Here are the containment operators:

   start with
   starts with
   begin with
   begins with
   end with
   ends with
   contains
   does not contain
   doesn't contain
   is in
   is contained by
   is not in
   is not contained by
   isn't contained by

Comparison Operators (Equality)

Here are the comparison operators (equality):

   =
   equal
   equals
   equal to
   is equal to
   ¤
   does not equal
   doesn't equal
   is not
   is not equal
   is not equal to

Comparison Operators (Precedence)

Here are the comparison operators (precedence):

   <
   comes before
   is less than
   is not greater than or equal
   is not greater than or equal to
   isn't greater than or equal
   isn't greater than or equal to
   less than
   >
   comes after
   greater than
   is greater than
   is not less than or equal
   is not less than or equal to
   isn't less than or equal
   isn't less than or equal to
   
   <=
   does not come after
   doesn't come after
   is less than or equal
   is less than or equal to
   is not greater than
   isn't greater than
   less than or equal
   less than or equal to
   u2264.gif
   >=
   does not come before
   doesn't come before
   greater than or equal
   greater than or equal to
   is greater than or equal
   is greater than or equal to
   u2265.gif
   is not less than
   isn't less than

Script 4.27 gives a few examples of Finder queries using the various operators.

Script 4.27.

   tell application "Finder"
       every item of folder "Documents" of home whose ¬
           name contains "Smith Project"
       every document file of folder "Pictures" of home whose ¬
           file type is in {"JPEG", "TIFF", "GIFf"}
       every document file of folder "Pictures" of home whose ¬
           name extension is not in {"jpg", "tif"}
       every folder of folder "Documents" of home whose ¬
           size is greater than 10000000
       every item of home whose name comes before "P"
   end tell

Compound Property Queries

You can limit the scope of searches by incorporating additional or optional search parameters in your queries.

For example, to add another property value to a query, use the term and followed by the new parameter, as in Script 4.28 (this example assumes Leopard is installed on your computer):

Script 4.28.

   tell application "Finder"
       get 1st item of folder "Applications" of the startup disk whose ¬
           name begins with "T" and name contains "Machine"
   end tell
   --> returns: application file "Time Machine.app" of folder "Applications"
   of startup disk of application "Finder"

Each additional comparison must be complete in itself. It cannot be a continuation of the previous comparison. Script 4.29 is an example that won't compile:

Script 4.29.

   tell application "Finder"
       get 1st item of folder "Applications" of the startup disk whose ¬
           name begins with "Q" and contains "Player" --> SYNTAX ERROR
   end tell

The proper syntax is shown in Script 4.30.

Script 4.30.

   tell application "Finder"
       get 1st item of folder "Applications" of the startup disk whose ¬
           name begins with "Q" and name contains "Player"
   end tell
   --> returns: application file "QuickTime Player.app" of folder
   "Applications" of startup disk of application "Finder"

There is no limit to the number of additional search parameters that can be added. For example, the query in Script 4.31 contains a search specification that has four comparisons.

Script 4.31.

   tell application "Finder" to ¬
       get every document file of folder "Pictures" of home whose ¬
       kind is "JPEG image" and name contains "Account" and ¬
       size is greater than or equal to 50000 and ¬
       size is less than or equal to 100000

Optional search specifications can be added to a query by using the term or, as in Script 4.32.

Script 4.32.

   tell application "Finder"
       get every document file of folder "Pictures" of home whose ¬
       file type is in {"JPEG", "TIFF"} or ¬
       name extension is in {"jpg", "tif", "tiff"}
   end tell

Any items meeting either of the search specifications are returned from the query.

Searches can contain both additional and optional specifications by using both the and and or terms.

The example in Script 4.33 encloses the additional specifications in parentheses so the logic of the query is easier to see. This is a good habit to develop, because it will help ensure that you've written your queries properly.

Script 4.33.

   tell application "Finder"
       get every document file of folder "Pictures" of home whose ¬
           (kind is "JPEG image" or kind is "TIFF image") and ¬
           name contains "Smith Project"
   end tell

The previous query returns a reference to every TIFF or JPEG image whose name contains the phrase Smith Project. Both conditions, the kind of the image and its name, must match before a reference is returned.

In addition to whose, the term where can be used whenever it will help make the statement read more smoothly. For an example, see Script 4.34.

Script 4.34.

   tell application "Finder"
       get every document file of folder "Pictures" of home where ¬
           its kind is "JPEG image"
   end tell

Note the use of the possessive term its to indicate ownership of the kind property. You can also use of it, as in where kind of it is "JPEG image".

  • + Share This
  • 🔖 Save To Your Account