Flash Reference Guide

The Flash bitmapData class is a tool you can use to construct dynamic bitmap images at processor runtime. What does this mean? You can create complex vector images that can be treated in the same way as bitmap images. To help you with your development, Macromedia has included a broad swath of methods that can be applied to a bitmapData object.

The bitmapData class is constructed of methods and properties you can control. The following is a complete list of all the methods:

1. ApplyFilter method
2. Clone method
3. ColorTransform method
4. CopyChannel method
5. CopyPixels method
6. Dispose method
7. Draw method
8. FillRect method
9. FloodFill method
10. GenerateFillRect method
11. GetColorsBoundRect method
12. GetPixel method
13. HitTest method
14. LoadBitmap method
15. Merge method
16. Noise method
17. PaletteMap method
18. PerlinNoise method
19. PixelDissolve method
20. Scroll method
21. SetPixel method
22. SetPixel32 method
23. Threshold method

The following is a list of properties:

1. Height
2. Rectangle
3. Transparent
4. Width

As you can see, the bitmapData class is very broad. In this section of the guide, you'll learn how to create a bitmapData object together with a selection of some of the methods used to manipulate the object.

Simple BitmapData Drawing

Let's get started. The following ActionScript allows you to build a simple bitmapData drawing. Note that you need to import the flash.display.BitmapData class. The class provides ActionScript with extra definition that allows you to construct the image.

Following the import statement is the new bitmapData object. The new object defines a region's width, height, transparency, and color.

For this example, a dynamic movie clip is created that's bound to the new bitmapData object.

import flash.display.BitmapData;
var myBitmapData:BitmapData = new BitmapData(100, 100, false, 0x00FF0000);
var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc.attachBitmap(myBitmapData, this.getNextHighestDepth());

The final result is a simple, red square. The region of the square is created from the myBitmapData object. The constructor defines the width, height, transparency, and color.

Using the ApplyFilter Method

The following ActionScript demonstrates how different filter effects can be applied to a bitmapData object. In this example, you can swap out different filter effects for either bevel, drop shadow, or blur.

When you use the ApplyFilter method, you must import the filters you want to use. Here, I have imported three filters:

import flash.display.BitmapData;
import flash.filters.BevelFilter;
import flash.filters.DropShadowFilter;
import flash.filters.BlurFilter;
import flash.geom.Point;

The following script creates the bitmapData object and an empty movie clip to which you can apply the bitmapData object:

var myBitmapData:BitmapData = new BitmapData(100, 80, true, 0xCCCCCCCC);
var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc.attachBitmap(myBitmapData, this.getNextHighestDepth());

Now, you need to create instances for each filter together with the settings for each filter. The following script sets up a bevel, blur, and drop shadow filter.

var filter:BevelFilter = new BevelFilter(5, 45, 0xFFFF00, .8, 0x0000FF, .8, 20, 20, 1, 3, "inner", false);
var filter2:BlurFilter = new BlurFilter(30, 30, 3);
var filter3:DropShadowFilter = new DropShadowFilter(20, 45, 0x000000, .5, 16, 17, 1, 3, false, false, false);

The method you need to focus on is the ApplyFilter method. Here, you can bind a filter by variable name. In this instance, the variable "filter" can be applied to add a bevel effect. You can swap this out with "filter2" and "filter3" to apply a blur and drop shadow effect.

myBitmapData.applyFilter(myBitmapData, myBitmapData.rectangle, new Point(0, 0), filter);

Try swapping the bold variable "filter" above for filter2 and filter3 to see the differences.

Using the PaletteMap Method

The PaletteMap method gives you control over adding color to regions of your bitmap. As with the other exercises, you'll need to import the correct classes and create the bitmapData object as well as the empty movie clips.

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;
var myBitmapData:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);
var mc:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc.attachBitmap(myBitmapData, this.getNextHighestDepth());

Now, you'll want to apply the fillRect method to create a red, rectangle object.

myBitmapData.fillRect(new Rectangle(51, 0, 50, 80), 0x0000FF00);

The PaletteMap is constructed of red, green, blue, and alpha. Here, the red and green values are being applied.

myMapPallette = function () {
  var redArray:Array = new Array(256);
  redArray[255] = 0x0000FF00;
  var greenArray:Array = new Array(256);
  greenArray[255] = 0x00FF0000;
  myBitmapData.paletteMap(myBitmapData, new Rectangle(0, 0, 100, 40), new Point(0, 0), redArray, greenArray, null, null);
};
A setInterval script will re-set the screen every half a second.

function myTimer():Void {
  myMapPallette();
}
var intervalID:Number = setInterval(myTimer, 500);

Try modifying the blue and alpha levels to tweak the PaletteMap method.

Using the Noise Method

To visually apply pixel-based distortion to an object, you need to use the Noise method. In this example, two rectangles will be created to demonstrate both the grayscale and color scale parameters in the Noise method.

import flash.display.BitmapData;
import flash.geom.Rectangle;
import flash.geom.Point;
var bitmapData_1:BitmapData = new BitmapData(100, 100, false, 0x00CCCCCC);
var bitmapData_2:BitmapData = new BitmapData(100, 100, false, 0x00FF0000);
var mc_1:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_1.attachBitmap(bitmapData_1, this.getNextHighestDepth());
var mc_2:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_2.attachBitmap(bitmapData_2, this.getNextHighestDepth());
mc_2._x = 101;

The following function controls the Noise method values for objects bitMapData_1 and bitMapData_2.

function myTimer():Void {
  bitmapData_1.noise((Math.floor(Math.random()*128)), 0, 255, 1, true);
  bitmapData_2.noise((Math.floor(Math.random()*128)));
}
var intervalID:Number = setInterval(myTimer, 50);

Noise is a logical distortion of pixels. For larger shapes, you need to use the PerlinNoise method.

Using the PerlinNoise Method

PerlinNoise is similar to Noise. The difference is that you can create shapes to act as the noise instead of just a pixel. The following example is very similar to the Noise method example above. The differences are highlighted below in bold.

import flash.display.BitmapData;
var bitmapData_1:BitmapData = new BitmapData(100, 80, false, 0x00CCCCCC);
var bitmapData_2:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);
var mc_1:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_1.attachBitmap(bitmapData_1, this.getNextHighestDepth());
var mc_2:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_2.attachBitmap(bitmapData_2, this.getNextHighestDepth());
mc_2._x = 101;
perlinNoise1 = function () {
  var randomNum:Number = Math.floor(Math.random()*10);
  bitmapData_1.perlinNoise(100, 80, 6, randomNum, false, true, 1, true, null);
};
perlinNoise2 = function () {
  var randomNum:Number = Math.floor(Math.random()*10);
  bitmapData_2.perlinNoise(100, 80, 4, randomNum, false, false, 15, false, null);
};
function myTimer():Void {
  trace(getTimer());
  perlinNoise1();
  perlinNoise2();
}
var intervalID:Number = setInterval(myTimer, 100);

When you run this example, you'll see that the shapes are created dynamically.

When To Use BitMap Data Class

As you can see, the bitMapData class can be very useful. For example, you can use the PerlinNoise method to create a simple animation that is less processor-intensive than a traditional vector animation.

import flash.display.BitmapData;
var bitmapData_2:BitmapData = new BitmapData(100, 80, false, 0x00FF0000);
var mc_2:MovieClip = this.createEmptyMovieClip("mc", this.getNextHighestDepth());
mc_2.attachBitmap(bitmapData_2, this.getNextHighestDepth());
mc_2._x = 101;
perlinNoise2 = function () {
  var randomNum:Number = Math.floor(Math.random()*10);
  bitmapData_2.perlinNoise(100, 80, 4, randomNum, false, false, 15, false, null);
};
function myTimer():Void {
  trace(getTimer());
  perlinNoise2();
  mc_2._x = ++mc_2._x;
  mc_2._y = ++mc_2._y;
}
var intervalID:Number = setInterval(myTimer, 25);