Publishers of technology books, eBooks, and videos for creative people

Home > Articles > Web Design & Development > Adobe ColdFusion

  • Print
  • + Share This
This chapter is from the book

Working with Inheritance

Frequently it is useful to have components that implement similar functionality in different ways. For example, you might have a circle component and a square component. Each has a draw method: The circle component draws a circle on the screen, and the square component draws a square. Each also has independent properties: for example, the circle has circumference, and the square has length. The two components also have a lot in common: They each have perimeter and area. The square and circle components are special cases of a shape; they have everything a shape has, plus more. Thus, it would make sense to create a single parent component called shape that has the information that is common to all types of shapes, and to have child components that inherit this information and also add their own. Thus, square, as a child of shape, would have all the things that shape has plus length, and it would implement its own variation of draw.

Just as we can use the word my to refer to a CFC's THIS scope ("my ID is 123 and my First Name is Fred..."), in inheritance, we can think of the words is a. A square is a shape. An actor is a person. A cat is a mammal. In these cases, actor, square, and cat are children of person, shape, and mammal. Some parents can exist by themselves; there can be a person who is not an actor. Some other parents, though, are abstract; shape can't draw itself without knowing what shape it is. Rather, the parent is intended as more of a handy template upon which more specific things can be based.

In a movie studio application, actors and directors are both types of people, with some properties that are common and some that are unique. So, for types of people, you could create a component to represent a person and have each of these variants inherit from it.

Listing 27.2 shows the basic person component. It has a first name and last name (stored in the THIS scope) and has one function that "shows" the person by outputting the first and last name.

Listing 27.2. person.cfc—The Basic person Component

<!---
  person.cfc
  Component that contains a "person", firstname and lastname only
  Modified by Ken Fricklas (kenf@fricklas.com)
  Modified: 8/1/2007
  Code from Listing 27.2
--->
<cfcomponent displayName="Person" hint="Parent Component - Person">

<cfparam name="THIS.firstName" default="John">
<cfparam name="THIS.lastName" default="Doe">

<cffunction name="showPerson" output="true" hint="showPerson in person.cfc" >
  <B>#THIS.firstName# #THIS.lastName#</B>
</cffunction>

</cfcomponent>

A component inherits from a parent component with the EXTENDS attribute of the <cfcomponent> tag. The value of the attribute is the name of the component upon which the new component should be based. Thus, a director component could consist of nothing more than this code:

<cfcomponent displayName="Movie Director" extends="person">
</cfcomponent>

Now, the director is an exact copy of the person component and has inherited all the properties and methods of its parent. A CFML page, then, could create an instance of the director and invoke the methods of the person component as though they were part of the director component:

<cfobject component="director" name="myDirector">
<cfoutput>#myDirector.showPerson()#</cfoutput>

Overriding Properties and Methods

Just because the parent does something doesn't mean that the child is stuck with it. The component can override parts of the parent component. If we want the director component to set the firstName and lastName properties to different values than those of the person component, we simply add code that redefines the values. The director, because it's the one being invoked, will take precedence. So the director component is now coded like this:

<cfcomponent displayName="Movie Director" extends="person">
  <cfset THIS.firstName = "Jim">
  <cfset THIS.lastName = "Jarofmush">
</cfcomponent>

When invoked from the CFML page, this component now will output "Jim Jarofmush" instead of "John Doe". The THIS scope assignments made in a child override those of its parent. Likewise, adding a showPerson function to the director component will override the showPerson function from the parent:

<cffunction name="showPerson" output="true" hint="showPerson in director.cfc">
  <B>A swell director named #THIS.firstName# #THIS.lastName#</B>
</cffunction>

Using the SUPER Scope

What if a child component needs to use the functionality in a method in its parent, but it has redefined that method already? In our director component, we could call the parent showPerson method, but we want to add our own information to it. We do this with the special scope SUPER. SUPER acts similarly to THIS, but instead of referring to a property or method in the current component, it refers to the property or method in the component's parent. We could redefine showPerson in the director component like this:

<cffunction name="showPerson" output="true" hint="showPerson in director.cfc">
  <B>A swell director</B> - #super.showPerson()#
</cffunction>

This code calls the showPerson method in the person component.

In addition to the child's being able to invoke functions that are really part of the parent component (and overriding them, if desired), the parent can call functions that are part of the child by referencing them in the instance's THIS scope. Say we added a function called showDetail to the director component:

<cfset THIS.credits = arrayNew(1)>
<cfset THIS.credits[1] = "The Phantom Dentist">
<cfset THIS.credits[2] = "Austin Showers">
<cfset THIS.credits[3] = "Men in Slacks II">

<cffunction name="showDetail" output="true">
  Credits include:
  <UL>
  <cfloop index="i" from="1" to="#arrayLen(THIS.credits)#">
  <LI>#THIS.credits[i]#</LI>
  </cfloop>
  </UL>
</cffunction>

We could then modify the showPerson function in the person component to optionally call showDetail:

<cffunction name="showPerson" output="true" hint="showPerson in person.cfc">
  <cfargument name="showDetail" required="false" type="boolean"
    default="false">
  <B>#THIS.firstName# #THIS.lastName#</B>
  <cfif arguments.showDetail>
    <BR>#THIS.showDetail()#
  </cfif>
 </cffunction>

Since the director component wants the showPerson method to call its showDetail method, we change its showPerson method to pass in this argument, like this:

<cffunction name="showPerson" output="true" hint="showPerson in director.cfc">
  <B>A swell director</B> - #super.showPerson(true)#
</cffunction>

In the calling template now, we can call the showPerson function in the director component:

<cfobject component="director" name="myDirector">
<cfoutput>#myDirector.showPerson()#</cfoutput>

The result of our showPerson function now will be a combination of showPerson from the person component and showDetail from the director component:

A swell director - Jim Jarofmush
Credits include:
. The Phantom Dentist
. Austin Showers
. Men in Slacks II

This technique can be useful when multiple components are descendents of the same parent but require slightly different methods. Say we based an actor component on the same "person" parent using this code:

<cfcomponent displayName="Movie Actor" extends="person">
  <cfset THIS.firstName = "Judi">
  <cfset THIS.lastName = "Dents">

<cffunction name="showDetail" output="true">
  Star of the hit <EM>The Importance of Being Sternest</EM>.
</cffunction>

</cfcomponent>

When the showPerson function is invoked, the appropriate showDetail function is used, depending on whether the component is an actor or director (see Listing 27.3).

Listing 27.3. index.cfm—Calling Components to Show Inheritance

<!--- instantiate an actor and a director --->
<cfobject component="director" NAME="myDirector">
<cfobject component="actor" NAME="myActor">
<!--- demonstrate that showPerson calls different showDetail functions for each --->
<cfoutput>
  Directed by:<br>
    #myDirector.showPerson()# <!--- overridden in the director component --->
  <br>
  Starring:<br>
    #myActor.showPerson(true)# <!--- must pass argument true to have the showPerson
call showDetail, since it's not overridden --->
</cfoutput>

This code results in this output:

Directed by:
A swell director - Jim Jarofmush
Credits include:
. The Phantom Dentist
. Austin Showers
. Men in Slacks II
Starring:
Judi Dents
Star of the hit The Importance of Being Sternest.

Must you use inheritance in your ColdFusion applications? Certainly not. But it can be very useful in ways similar to other code-reuse techniques. Components can be built-in "branches," as in a family tree with chains of ancestral parent components, each providing base functionality to their children.

Component packages can help with this type of organization, too, to make applications more easily maintainable. In that case, the extends="..." attribute uses the same package path syntax as a <cfinvoke> tag. For example, to inherit from a component called "person" in the package myApp.components, the <cfcomponent> tag would be coded like this:

<cfcomponent extends="myApp.components.person">
  • + Share This
  • 🔖 Save To Your Account

Related Resources

There are currently no related titles. Please check back later.